✒️ABAP Los Eventos
ABAP Los Eventos
1- Disparar y manejar eventos
En objetos ABAP hay ciertos métodos que se conocen como disparadores (triggers) y otros que se conocen como maneadores (handlers). Los triggers son los métodos que disparan un evento, mientras que los handlers son los métodos que se ejecutan cuando ocurre un evento.
Para disparar un evento una clase tiene:
- Declarar el evento en la declarativa
- Disparar el evento en uno de sus metodos
EVENTS <evt> EXPORTING..... VALUE(<ei>) TYPE type [OPTINAL]..
Para declarar eventos estáticos:
CLASS-EVENTS <evt>...
Cuando se declara un evento se puede usar la adición EXPORTING para especificar paramentos que se pasa al manejado del evento. Los parámetros se pasan siempre por valor.
Los eventos dependientes de instancia siempre contienen el parámetro implícito SENDER, el cual tiene el tipo de una referencia al tipo o a la interface en la cual el evento es declarado.
Un evento dependiente de instancia en un clase puede ser disparado por cualquier método en la clase. Los eventos estáticos son disparados por métodos estáticos. Para disparar un evento en un método se usa la siguiente sentencia:
RAISE EVENT <evt> EXPORTING... <ei> = <f i>...
Por cada paramento formal que no este definido como opcional se tiene que pasar el correspondiente paramento real en la adición EXPORTING. La referencia a si mismo ME es pasada automáticamente al parámetro implícito SENDER.
Es importante no confundir este concepto de eventos en la POO con los eventos del entorno de ejecución ABAP, tales como son el evento LOAD OF PROGRAM, INITIALIZATION, START OF SELECCTION o END OF SELECTION. Estos son conceptos totalmente diferentes.
2- Eventos manejadores
Se usa para ejecutar una serie de métodos.
- Estar definidos como eventos manejadores (handler) de ese evento.
- Estar registrados en tiempo de ejecución para el evento.
Una clase puede contender métodos manejadores de eventos para eventos tanto de su propia clase como de otras clases, para declarar un método manejado de eventos dependiente de instancia se usa la siguiente sentencia:
METHODS <meth> FOR EVENT <evt> of <cif> IMPORTING ... <ei>..
Para los métodos estáticos se usa la mía sentencia con CLASS_METHODS en vez de METHODS.
La interface de un método manejado de eventos solo puede tener contener paramentos formales definidos en la declaración del evento. Los atributos de los parámetros también son adoptados por el evento.
EN método manejado de eventos no tiene por que usar todos los parámetros pasados en la sentencia RAISE EVENT.
3- Registro de métodos manejadores de eventos
Para permitir a un método manejado de eventos reaccionar a un evento, se tiene que determinar en un tiempo de ejecución el disparador al cual va a reaccionar. Esto se hace con las siguiente sentencia:
SET HANDLER... <hi>...[FOR]...
Hay cuatro tipos diferentes de eventos:
- Eventos dependientes de instancia declarados en una clase
- Eventos dependientes de instancia declarados en una interface
- Eventos estáticos declarados en una clase
- Eventos estáticos declarados en una interface
El efecto de la sentencia SET HANDLER depende de los cuatros casos que detallamos tenga lugar.
Para uno evento dependiente de instancia se tiene que usar la adición FOR para especificar la instancia para la cua se quiere registrar el manejado. Se puede modificar una sola instancia como disparador usando una variable reverenciada:
SET HAMDLER...<hi>....FOR <ref>.
O se puede registrar el manejado para todas las instancias que puedan disparar el evento:
SET HANDLER...<hi>...FOR ALL INSTANCES.
En este caso el registro se aplica incluso a las instancias que aun no han sido creadas cuando se registra el manejado.
No se puede usar la adición FOR para los eventos estáticos
SET HANDLER ...<hi>...
El registro se aplica automáticamente a la clse entera o todas las clases que implementan la interface que contiene el evento estático. En el caso de las interfaces, el registro también se aplica a las clases que aun no han sido cargadas cuando el manejado se registra.
4- Coordinación en el manejo de eventos
Después de la sentencia RAISE EVENT, todos los métodos manejadores registrados son ejecutados antes de que la siguiente sentencia sea procesada (manejo de eventos sincrónico) Si un manejado de eventos desencadena eventos, los correspondientes métodos manejadores de eventos son ejecutados antes de que el método manejado original continúe.
Para evitar la posibilidad infinita de un bucle, actualmente los eventos se pueden anidar 64 niveles.
Los métodos manejadores de eventos son ejecutados en el orden en el que son registrados.
Los manejadores de eventos son registrados dinámicamentes, no se puede saber el orden en el que serán procesados, por esto se debe programas todos los manejadores de eventos como si fuesen a ejecutar todos simultáneamente.
Los eventos están sujetos a la misma estructura de visibilidad de los demás componentes de una clase. Por lo tanto pueden ser públicos, protegidos o privados.
Los métodos manejadores de eventos también tienen atributos de visibilidad.
La visibilidad de un evento determina quien está autorizado para controlar o manejar el evento.
Los eventos que son públicos pueden ser utilizados por cualquiera.
Los eventos que son protegidos solo pueden ser utilizados por usuarios dentro de la clase o sus sub clases.
Los eventos que son privados solo pueden ser utilizados dentro de la clase. La visibilidad de un método manejador de eventos determina quien está autorizado para registrar el método, es decir en qué lugares podremos utilizar la sentencia SET HANDLER.
Los métodos manejadores de eventos que son públicos pueden ser utilizados en cualquier lugar.
Los métodos manejadores de eventos que son protegidos, pueden ser utilizados por usuario dentro de la clase o sus subclases.
Los métodos manejadores de eventos que son privados solo pueden ser utilizados por el usuario dentro de la clase.
Los métodos manejadores de eventos pueden tener la misma visibilidad o más restringida de aquellos eventos a los que se refiere.
5-Ejemplo del manejo de eventos
La clase CONTADOR implementa un contador, se desencadena el evento valor_critico cuando el valor UMBRAL es excedido se visualiza la diferencia. La clase MANEJADOR puede manejar las excepciones en la clase CONTADOR. El manejado es registrado en tiempo de ejecución para todas las variables referenciadas que apunten al objeto.
CLASS contador DEFINITION.
PUBLIC SECTION.
METHODS incrementar_contador.
EVENTS valor_critico EXPORTING value(exceso) TYPE i.
PRIVATE SECTION.
DATA: cuenta TYPE i,
umbral TYPE i VALUE 10.
ENDCLASS. "contador DEFINITION
CLASS contador IMPLEMENTATION.
METHOD incrementar_contador.
DATA diferencia TYPE i.
ADD 1 TO cuenta.
IF cuenta > umbral.
diferencia = cuenta - umbral.
RAISE EVENT valor_critico EXPORTING exceso = diferencia.
ENDIF.
ENDMETHOD. "incrementar_contador
ENDCLASS. "contador IMPLEMENTATION
CLASS manejador DEFINITION.
PUBLIC SECTION.
METHODS manejar_exceso FOR EVENT valor_critico OF contador
IMPORTING exceso.
ENDCLASS. "manejador DEFINITION
CLASS manejador IMPLEMENTATION.
METHOD manejar_exceso.
WRITE: / 'El Exceso es: ', exceso.
ENDMETHOD. "manejar_exceso
ENDCLASS. "manejador IMPLEMENTATION
En evento START-OF-SELECTION se declara:
DATA: cuenta TYPE REF TO contador,
manejador TYPE REF TO manejador.
START-OF-SELECTION.
CREATE OBJECT: cuenta, manejador.
SET HANDLER manejador->manejar_exceso FOR ALL INSTANCES.
DO 20 TIMES.
CALL METHOD cuenta->incrementar_contador.
ENDDO.
Y la salida por pantalla del programa será la que vemos a continuación:
El exceso es: 1
El exceso es: 2
El exceso es: 3
El exceso es: 4
El exceso es: 5
El exceso es: 6
El exceso es: 7
El exceso es: 8
El exceso es: 9
El exceso es: 10
 
 
 
Sobre el autor
Publicación académica de Juan Carlos Pavicich, en su ámbito de estudios para la Carrera Consultor ABAP.
Juan Carlos Pavicich
Profesión: Técnico Informático - Argentina - Legajo: VR91L
✒️Autor de: 116 Publicaciones Académicas
🎓Egresado de los módulos:
Disponibilidad Laboral: FullTime
Presentación:
Tengo el agrado de dirigirme a ud/s con el objeto de mencionar mi experiencia y conocimientos técnicos necesarios para desarrollar actividades en el rubro de su empresa.
Certificación Académica de Juan Pavicich