✒️ABAP La ejecución de fondo
ABAP La ejecución de fondo
Ejecución de Fondo
Existen dos formas de ejecutar un programa en ABAP: Online y Batch. En la ejecución Online el programa se ejecuta
al momento de presionar F8 y los resultados de la ejecución se producen de manera inmediata.
Esta forma de ejecución es conveniente para los programas donde se requiere interacción con el usuario
o cuando el tiempo de ejecución es muy poco.
Pero en ciertos otros casos, especialmente hablando en un ambiente real de trabajo,
el tiempo de procesamiento de un programa podría ser muy alto.
Esto se puede deber a que el programa tiene muchos accesos a base de datos, que tienen millones de registros,
a la ejecución de múltiples transacciones o a otras varias razones.
Para estos casos que acabamos de mencionar, va a ser conveniente la ejecución Batch o de fondo.
Veamos un ejemplo paso a paso de como ejecutar un programa de fondo.
Supongamos que tenemos el programa ABAP ZPRUEBA_FONDO_B que obtiene
los registros de la tabla ZTABLA_USUARIOS y los imprime por pantalla.
DATA: ti_usuarios TYPE STANDARD TABLE OF ZOQS36A_USUARIOS,
st_usuarios LIKE LINE OF ti_usuarios.
START-OF-SELECTION.
CLEAR ti_usuarios.
REFRESH ti_usuarios.
SELECT dni nombre_ape estado_usu
FROM ZOQS36A_USUARIOS
INTO CORRESPONDING FIELDS OF TABLE ti_usuarios.
LOOP AT ti_usuarios INTO st_usuarios.
WRITE:/ st_usuarios-dni,
st_usuarios-nombre_ape,
st_usuarios-estado_usu.
ENDLOOP.
Ahora vamos a crear el nuevo programa ABAP ZPRUEBA_FONDO el cual cumplirá el rol
de programa padre del programa ZPRUEBA_FONDO_B.
Lo primero que debemos hacer es crear un Job. Para esto le asignamos un nombre a la variable V_JOBNAME y luego ejecutamos
la función JOB_OPEN. Para modularizar vamos a crear la subrutina ABRIR_JOB que tendrá el siguiente código.
FORM ABRIR_JOB .
CONCATENATE 'ZPRUEBA_FUNDO_' sy-datum INTO v_jobname.
CALL FUNCTION 'JOB_OPEN'
EXPORTING
jobname = v_jobname
IMPORTING
jobcount = v_jobcount
EXCEPTIONS
cant_create_job = 1
invalid_job_data = 2
jobname_missing = 3
OTHERS = 4.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
ENDFORM. " ABRIR_JOB
Lo que sigue es lanzar el Job. Para esto vamos a crear la subrutina LANZAR_JOB, que ejecutará la sentencia SUBMIT,
la cual se utiliza para ejecutar un programa dentro de otro programa y con el agregado de la cláusula VIA JOB NUMBER
la ejecución del programa se realizará de fondo.
Mediante la sentencia SUBMIT se pueden pasar parámetros al programa llamado,
los cuales deben existir en la pantalla de selección de éste.
FORM LANZAR_JOB .
* Lanzo el Job
SUBMIT ZM04L07C01_ESTQS36A_BATCH
USER sy-uname "usuario que ejecuta
VIA JOB v_jobname
NUMBER v_jobcount
AND RETURN.
ENDFORM. " LANZAR_JOB
Con el agregado de la cláusula AND RETURN el programa llamador permanece en espera mientras se ejecuta el programa llamado.
Cuando el programa llamado termina, se devuelve el control al programa llamador.
Con el agregado de la cláusula AND RETURN el programa llamador permanece en espera mientras se ejecuta el programa llamado.
Cuando el programa llamado termina, se devuelve el control al programa llamador.
Luego debemos cerrar el Job mediante la función JOB_CLOSE. Para esto vamos a crear la subrutina CERRAR_JOB.
FORM CERRAR_JOB .
CALL FUNCTION 'JOB_CLOSE'
EXPORTING
jobcount = v_jobcount
jobname = v_jobname
strtimmed = 'X' "Comienza de inmediato
EXCEPTIONS
cant_start_immediate = 1
invalid_startdate = 2
jobname_missing = 3
job_close_failed = 4
job_nosteps = 5
job_notex = 6
lock_failed = 7
invalid_target = 8
OTHERS = 9.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ELSE.
WRITE 'Se lanzo el Job, para visualizarlo ir a la Trx SM37'.
ENDIF.
ENDFORM. " CERRAR_JOB
Por último, después de cerrar el Job, imprimimos por pantalla el mensaje "Se lanzo el Job, para visualizarlo ir a la Trx SM37".
Ahora vamos a ejecutar Online el programa ZPRUEBA_FONDO presionando F8. Veremos en la pantalla el mensaje "Se lanzo el Job,
para visualizarlo ir a la Trx SM37", por lo tanto vamos a ir a buscar el resultado a la transacción SM37. Allí presionamos F8 o Ejecutar.
Transacción SM37 (Administracion de JOB)
Utilizaremos la transacción estándar SM37 para visualizar los jobs procesados en el sistema SAP.
De cada job podremos visualizar distintos datos tales como el ID, el usuario SAP que lo ejecutó,
el status (planeado, liberado, listo, activo, terminado o cancelado), la fecha y hora de inicio, la duración y el retraso.
Identificamos nuestro proceso, lo tildamos y presionamos el botón Spool.
Ahora vemos el pedido del Job correspondiente a nuestro programa.
Finalmente, presionamos el botón de visualización y vemos el resultado del procesamiento
Programa ejemplos de la lección
Programa que consulta el listado de usuarios y posteriormente lo imprime en pantalla
 
 
 
Sobre el autor
Publicación académica de Alex Francisco Lemos Collazos, en su ámbito de estudios para la Carrera Consultor ABAP.
Alex Francisco Lemos Collazos
Profesión: Ingeniero en Sistemas - Colombia - Legajo: QS36A
✒️Autor de: 174 Publicaciones Académicas
🎓Cursando Actualmente: Master S/4HANA Material Management
🎓Egresado de los módulos:
- Máster Material Management en SAP S/4HANA LOGISTIC
- Carrera Consultor ABAP Nivel Avanzado
- Carrera Consultor ABAP Nivel Inicial
- Carrera Consultor en SAP SD Nivel Inicial