✒️ABAP / El Batch Input utilizando Call transaction Por Alex Lemos Collazos

Mi primer Batch Input utilizando CALL TRANSACTION

Vamos a crear nuestro primer Batch Input utilizando la técnica de CALL TRANSACTION.

El objetivo del Batch Input será la carga inicial de datos de la tabla ZTABLA_USUARIOS.

Para ello, vamos a crear un archivo de texto con registros que cumplan con la estructura de la tabla ZTABLA_USUARIOS,

sin tener en cuenta al campo mandante.

Archivo para correcto funcionamiento

00121567432Joaquin Perez ALarreo Alvarez 3454 134512081967S

00131987623Barbara Pereira ALavalleja 543 145623091987S

00127982134Eugenia Herrera AGuido 56 167507041979S

Como lo que vamos a hacer será la carga inicial de la tabla de usuarios, borraremos su contenido previamente a la ejecución de este ejemplo.

Ahora, seguiremos los pasos que establecimos en la primer lección de la unidad.

Paso 1ero. : Declaración de datos propios del batch input

Declaramos una tabla interna y una estructura, ambas del tipo BDCDATA, otra tabla interna del tipo BDCMSGCOLL con su estructura,

que servirán para almacenar los mensajes que se produzcan cuando ejecutemos el CALL TRANSACTION, la tabla interna de usuarios,

que contendrá los datos que levantemos del archivo de entrada y una tabla para mostrar por pantalla los errores entre otras declaraciones.

* Tabla del BI con la estructura de BDCDATA

DATA: BEGIN OF ti_bdc_data OCCURS 0.

INCLUDE STRUCTURE bdcdata.

DATA: END OF ti_bdc_data.

* Estructura del BI

DATA: st_bdc_data TYPE bdcdata.

* Tabla de mensajes

DATA: BEGIN OF ti_messages OCCURS 0.

INCLUDE STRUCTURE bdcmsgcoll.

DATA: END OF ti_messages.

* Estructura de mensajes

DATA: st_messages TYPE bdcmsgcoll.

* Tabla de usuarios

DATA: BEGIN OF ti_archivo OCCURS 0,

mandt TYPE mandt,

dni TYPE zcvs_dni,

nombre_ape TYPE zcvs_nombre_ape,

estado_usu TYPE zcvs_estado_usu,

direccion TYPE zcvs_direccion,

codigo_postal TYPE zcvs_codigo_postal,

fecha_nac TYPE zcvs_fecha_nac,

estado_civil TYPE zcvs_estado_civil,

END OF ti_archivo.

DATA: st_archivo LIKE LINE OF ti_archivo.

"DATA: ti_archivo TYPE STANDARD TABLE OF zcvs_usuarios,

" st_archivo LIKE LINE OF ti_archivo.

* Tabla de errores

DATA: BEGIN OF ti_errores OCCURS 0,

dni TYPE zcvs_dni,

descripcion(100) TYPE c,

END OF ti_errores.

Estructura BDCMSGCOLL

Esta estructura estándar del sistema es utilizada para definir la tabla interna que almacenará los mensajes del batch input.

Paso 2do. : Lectura de datos de archivo de entrada

Ejecutamos el método GUI_UPLOAD para levantar el archivo de entrada con la información para generar el Batch Input.

* Se abre el archivo de entrada para lectura

CALL METHOD cl_gui_frontend_services=>gui_upload

EXPORTING

filename = vl_file

filetype = 'ASC'

has_field_separator = ''

CHANGING

data_tab = ti_archivo[]

EXCEPTIONS

file_open_error = 1

file_read_error = 2

no_batch = 3

gui_refuse_filetransfer = 4

invalid_type = 5

no_authority = 6

unknown_error = 7

bad_data_format = 8

header_not_allowed = 9

separator_not_allowed = 10

header_too_long = 11

unknown_dp_error = 12

access_denied = 13

dp_out_of_memory = 14

disk_full = 15

dp_timeout = 16

not_supported_by_gui = 17

error_no_gui = 18

OTHERS = 19.

Paso 3ero. : Carga de la tabla BDCDATA

Para cargar la tabla BDCDATA utilizamos la subrutina BDC_FIELD, que vimos en la lección anterior.

Antes debemos inicializar la tabla interna del Batch Input y la de los mensajes.

Como vamos a ingresar más de un registro, tendremos que manejar indices para saber en que fila de la pantalla estamos cargando los datos.

Esto lo solucionamos fácilmente, concatenando al nombre del campo el número de fila que le corresponde en la pantalla entre paréntesis.

FORM cargo_tabla_bdcdata .

CLEAR: ti_bdc_data, ti_messages.

REFRESH: ti_bdc_data, ti_messages.

* Ingreso a la Primer pantalla y presiono boton de mantenimiento

PERFORM bdc_field USING 'X' 'SAPMSVMA' '0100'.

PERFORM bdc_field USING ' ' 'VIEWNAME' 'ZCVS_USUARIOS'.

PERFORM bdc_field USING ' ' 'BDC_OKCODE' '=UPD'.

* Presiono boton de nuevas entradas

PERFORM bdc_field USING 'X' 'SAPLZCVS_USUARIOS' '0001'.

PERFORM bdc_field USING ' ' 'BDC_OKCODE' '=NEWL'.

ADD 1 TO v_indice.

PERFORM completo_ceros_izq.

* Cargo datos del usuario

PERFORM bdc_field USING 'X' 'SAPLZCVS_USUARIOS' '0001'.

CLEAR v_campo.

CONCATENATE 'ZCVS_USUARIOS-DNI(' v_indice ')' INTO v_campo.

PERFORM bdc_field USING ' ' v_campo st_archivo-dni.

CLEAR v_campo.

CONCATENATE 'ZCVS_USUARIOS-NOMBRE_APE(' v_indice ')' INTO v_campo.

PERFORM bdc_field USING ' ' v_campo st_archivo-nombre_ape.

CLEAR v_campo.

CONCATENATE 'ZCVS_USUARIOS-ESTADO_USU(' v_indice ')' INTO v_campo.

PERFORM bdc_field USING ' ' v_campo st_archivo-estado_usu.

CLEAR v_campo.

CONCATENATE 'ZCVS_USUARIOS-DIRECCION(' v_indice ')' INTO v_campo.

PERFORM bdc_field USING ' ' v_campo st_archivo-direccion.

CLEAR v_campo.

CONCATENATE 'ZCVS_USUARIOS-CODIGO_POSTAL(' v_indice ')' INTO v_campo.

PERFORM bdc_field USING ' ' v_campo st_archivo-codigo_postal.

CLEAR v_campo.

CONCATENATE 'ZCVS_USUARIOS-FECHA_NAC(' v_indice ')' INTO v_campo.

PERFORM bdc_field USING ' ' v_campo st_archivo-fecha_nac.

CLEAR v_campo.

CONCATENATE 'ZCVS_USUARIOS-ESTADO_CIVIL(' v_indice ')' INTO v_campo.

PERFORM bdc_field USING ' ' v_campo st_archivo-estado_civil.

* Grabo los Registros

PERFORM bdc_field USING ' ' 'BDC_OKCODE' '=SAVE'.

* Cierro la segunda pantalla

PERFORM bdc_field USING 'X' 'SAPLZCVS_USUARIOS' '0001'.

PERFORM bdc_field USING ' ' 'BDC_OKCODE' '=ENDE'.

* Cierro la primer pantalla

PERFORM bdc_field USING 'X' 'SAPMSVMA' '0100'.

PERFORM bdc_field USING ' ' 'BDC_OKCODE' '/EENDE'.

ENDFORM. " CARGO_TABLA_BDC

Paso 4to. : Ejecución de la sentencia Call Transaction

Ahora vamos a ejecutar la sentencia CALL TRANSACTION. La sintaxis de la sentencia es la siguiente:

* Call transaction

CALL TRANSACTION v_cod_trans USING ti_bdc_data

MODE v_modo

UPDATE 'A' "v_update

MESSAGES INTO ti_messages.

IF NOT sy-subrc IS INITIAL.

v_error = 'X'.

ENDIF.

Veamos en detalle cada una de las opciones.

USING:

aquí especificamos la tabla BDCDATA que se utilizará.

MODE:

determina el modo de procesamiento que utilizará el Batch Input. Los modos posibles de procesamiento son:

Modo Efecto

A Procesamiento con la visualización de todas las pantallas. Es el valor por default.

E Procesamiento donde se muestran las pantallas solo si ocurre un error.

Si se alcanza un breakpoint, se termina el procesamiento con SY-SUBRC igual a 1001.

El campo SY-MSGTY contendrá "S", SY-MSGID contendrá "00", SY-MSGNO contendrá "344",

SY-MSGV1 contendrá "SAPMSSY3" y SY-MSGV2 contendrá el "0131".

N Procesamiento donde no se muestran las pantallas.

P Procesamiento donde no se muestran las pantallas.

Si se alcanza un breakpoint, se pasa el control al debugger.

Es conveniente utilizar una variable para asignar el modo de procesamiento a un Batch Input.

De esta forma podremos modificar su valor dinámicamente, durante la ejecución del programa.

UPDATE:

determina el modo de actualización de los cambios que producirá el Batch Input. Los modos posibles son:

Update Efecto

A Actualización Asincrónica.

La actualización se produce de igual forma a la que sucede si utilizamos la sentencia COMMIT WORK.

Valor por defecto.

S Actualización Sincrónica.

La actualización se produce de igual forma a la que sucede si utilizamos la sentencia COMMIT WORK AND WAIT.

L Actualización Local.

MESSAGES INTO:

con el uso de esta opción, todos los mensajes generados durante el procesamiento del Batch Input son almacenados en una tabla interna de tipo BDCMSGCOLL. Para armar los mensajes, vamos a utilizar la función MESSAGE_PREPARE tal como vemos a continuación:

IF sy-subrc = 0.

v_msg_id = st_messages-msgid .

v_msg_no = st_messages-msgnr.

v_msg_v1 = st_messages-msgv1.

v_msg_v2 = st_messages-msgv2.

v_msg_v3 = st_messages-msgv3.

v_msg_v4 = st_messages-msgv4.

CALL FUNCTION 'MESSAGE_PREPARE'

EXPORTING

msg_id = v_msg_id

msg_no = v_msg_no

msg_var1 = v_msg_v1

msg_var2 = v_msg_v2

msg_var3 = v_msg_v3

msg_var4 = v_msg_v4

IMPORTING

msg_text = v_mensaje

EXCEPTIONS

function_not_completed = 1

message_not_found = 2

OTHERS = 3.

IF sy-subrc <> 0.

MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno

WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

ENDIF.

CLEAR st_errores.

st_errores-descripcion = v_mensaje.

Ahora que ya terminamos con todos los pasos del Batch Input, vamos a ejecutarlo con modo de procesamiento "A",

que nos permite ver el paso a paso de las actualizaciones.

Lo primero que hacemos es ingresar a la transacción SM30 con el nombre de la tabla y presionamos el botón Actualizar (Maintain).

Luego presionamos el botón Entradas nuevas (New Entries).

Se cargan todos los campos del registro y presionamos grabar.

Finalmente salimos de la transacción y repetiremos esta secuencia de pasos por cuantos registros de usuario ingresemos en la tabla.

La sentencia CALL TRANSACTION también es muy utilizada en reportes, para acceder a una transacción determinada,

a partir de los datos presionados en pantalla, con el agregado de la cláusula AND SKIP FIRST SCREEN.