Unidad-5-Lección-7: Eventos
1) Disparar y manejar eventos.
En los objetos ABAP hay ciertos métodos que se conocen como disparadores (triggers) y otros como manejadores (handlers). Los Triggers son los métodos que disparan un evento, mientras que los handlers son los métodos que se ejecutan cuando ocurre un evento.
Para disparar un evento una clase tiene que:
· Declarar el evento en la parte declarativa.
· Disparar el evento en uno de sus métodos.
Los eventos se declaran en la parte declarativa de una clase o en una interface.
Para declarar eventos dependientes de instancia se usa la sentencia:
EVENTS <evt> EXPORTING...VALUE(<ei>)TYPE type [OPTIONAL]..
Para declarar eventos estáticos se usa la sentencia:
CLASS-EVENTS <evt>…
Cuando se declara un evento se puede usar la adición EXPORTING para especificar parámetros que se pasan al manejador del evento. Los parámetros se pasan siempre por valor.
Los eventos dependientes de instancia siempre contienen el parámetro implícito SENDER, el cual tiene el tipo de una referencia al tipo o a la interface en la cual el evento es declarado. Un evento dependiente de instancia en una clase puede ser disparado por cualquier método en la clase. Los eventos estáticos son disparados por métodos estáticos. Para disparar un evento en un método se usa la sentencia:
RAISE EVENT <evt> EXPORTING...<ei> = <f i>…
Por cada parámetro formal que no esté definido como opcional se tiene que pasar el correspondiente parámetro real en la adición EXPORTING. La referencia a si mismo ME es pasada automáticamente al parámetro implícito SENDER.
NOTA (Audio Tip): Es importante no confundir este concepto de eventos en la POO con los eventos del entorno de ejecución ABAP, tales como son el evento LOAD OF PROGRAM, INITIALIZATION, START OF SELECCTION o END OF SELECTION. Estos son conceptos totalmente diferentes.
2) Eventos manejadores.
Se usan para ejecutar una serie de métodos; los cuales tienen que:
Estar definidos como eventos manejadores (handlers) de ese evento.
· Estar registrados en tiempo de ejecución para el evento.
Una clase puede contener métodos manejadores de eventos para eventos tantos de su propia clase como de otras clases. Para declarar un método manejador de eventos dependiente de instancia se usa la sentencia:
METHODS <meth> FOR EVENT <evt> OF <cif> IMPORTING.. <ei>…
Para métodos estáticos se usa la misma sentencia con CLASS-METHODS en vez de METHODS.
La interface de un método manejador de eventos solo puede contener parámetros formales definidos en la declaración del evento. Los atributos de los parámetros también son adoptados por el evento.
El método manejador de eventos no tiene por qué usar todos los parámetros pasados en la sentencia RAISE EVENT.
3) Registro de métodos manejadores de eventos
Para permitir a un método manejador de eventos reaccionar a un evento, se tiene que determinar en tiempo de ejecución el disparador al cual va a reaccionar. Esto se hace con la sentencia:
SET HANDLER... <hi>... [FOR]…
Esta sentencia relaciona los métodos manejadores de eventos con sus correspondientes métodos. Hay cuatro tipos diferentes de eventos:
· Eventos dependientes de instancia declarados en una clase.
· Eventos dependientes de instancia declarados en una interface.
· Eventos estáticos declarados en una clase.
· Eventos estáticos declarados en una interface.
La sintaxis y el efecto de la sentencia SET HANDLER dependen de cuál de los cuatro casos que detallamos tenga lugar.
Para un evento dependiente de instancia se tiene que usar la adición FOR para especificar la instancia para la cual se quiere que registrar el manejador. Se puede especificar una sola instancia como disparador usando una variable referenciada:
SET HANDLER..<hi>...FOR <ref>.
O se puede registrar el manejador para todas las instancias que puedan disparar el evento:
SET HANDLER... <hi>...FOR ALL INSTANCES.
En este caso el registro se aplica incluso a las instancias que aún no han sido creadas cuando se registra el manejador. No se puede usar la adición FOR para los eventos estáticos:
SET HANDLER... <hi>...
El registro se aplica automáticamente a la clase entera o a todas las clases que implementan la interface que contiene el evento estático. En el caso de las interfaces, el registro también se aplica a las clases que aún no han sido cargadas cuando el manejador se registra.
4) Coordinación en el manejo de eventos
Después de la sentencia RAISE EVENT, todos los métodos manejadores registrados son ejecutados antes de que la siguiente sentencia sea procesada (manejo de eventos sincrónico). Si un método manejador de eventos desencadena eventos, los correspondientes métodos manejadores de eventos son ejecutados antes de que el método manejador original continúe.
Para evitar la posibilidad de un bucle infinito, actualmente los eventos solo se pueden anidar 64 niveles.
NOTA: Los métodos manejadores de eventos son ejecutados en el orden en el que son registrados.
Debido a que los manejadores de eventos son registrados dinámicamente, no se puede saber el orden en el que serán procesados. Por esto se deben programar todos los manejadores de eventos como si se fuesen a ejecutar todos simultáneamente.
NOTA (Audio Tip 2): Los eventos están sujetos a la misma estructura de visibilidad de los demás componentes de una clase. Por lo tanto pueden ser públicos, protegidos o privados. Los métodos manejadores de eventos también tienen atributos de visibilidad.
La visibilidad de un evento determina quien está autorizado para controlar o manejar el evento.
Los eventos que son públicos pueden ser utilizados por cualquiera.
Los eventos que son protegidos solo pueden ser utilizados por usuarios dentro de la clase o sus sub clases.
Los eventos que son privados solo pueden ser utilizados dentro de la clase. La visibilidad de un método manejador de eventos determina quien está autorizado para registrar el método, es decir en qué lugares podremos utilizar la sentencia SET HANDLER.
Los métodos manejadores de eventos que son públicos pueden ser utilizados en cualquier lugar.
Los métodos manejadores de eventos que son protegidos, pueden ser utilizados por usuario dentro de la clase o sus subclases.
Los métodos manejadores de eventos que son privados solo pueden ser utilizados por el usuario dentro de la clase.
Los métodos manejadores de eventos pueden tener la misma visibilidad o más restringida de aquellos eventos a los que se refiere.
5) Ejemplo del manejo de eventos
El siguiente ejemplo muestra cómo se trabaja con eventos en los objetos ABAP.
La clase CONTADOR implementa un contador. Se desencadena el evento valor_critico cuando el valor UMBRAL es excedido y se visualiza la diferencia. La clase MANEJADOR puede manejar las excepciones en la clase CONTADOR. El manejador es registrado en tiempo de ejecución para todas las variables referenciadas que apunten al objeto.
CLASS contador DEFINITION.
PUBLIC SECTION.
METHODS incrementar_contador.
EVENTS valor_critico EXPORTING value(exceso) TYPE i.
PRIVATE SECTION.
DATA: cuenta TYPE i,
umbral TYPE i VALUE 10.
ENDCLASS. "contador DEFINITION
CLASS contador IMPLEMENTATION.
METHOD incrementar_contador.
DATA diferencia TYPE i.
ADD 1 TO cuenta.
IF cuenta > umbral.
diferencia = cuenta - umbral.
RAISE EVENT valor_critico EXPORTING exceso = diferencia.
ENDIF.
ENDMETHOD. "incrementar_contador
ENDCLASS. "contador IMPLEMENTATION
CLASS manejador DEFINITION.
PUBLIC SECTION.
METHODS manejar_exceso FOR EVENT valor_critico OF contador
IMPORTING exceso.
ENDCLASS. "manejador DEFINITION
CLASS manejador IMPLEMENTATION.
METHOD manejar_exceso.
WRITE: / 'El Exceso es: ', exceso.
ENDMETHOD. "manejar_exceso
ENDCLASS. "manejador IMPLEMENTATION
En evento START-OF-SELECTION se declara:
DATA: cuenta TYPE REF TO contador,
manejador TYPE REF TO manejador.
START-OF-SELECTION.
CREATE OBJECT: cuenta, manejador.
SET HANDLER manejador->manejar_exceso FOR ALL INSTANCES.
DO 20 TIMES.
CALL METHOD cuenta->incrementar_contador.
ENDDO.
Y la salida por pantalla del programa será la que vemos a continuación:
El exceso es: 1
El exceso es: 2
El exceso es: 3
El exceso es: 4
El exceso es: 5
El exceso es: 6
El exceso es: 7
El exceso es: 8
El exceso es: 9
El exceso es: 10