5° Interfaces
1- Introducción a Interfaces
- Las Clases, sus Instancias (objetos) y el acceso a los Objetos usando Variables Referenciadas son la base de la Programación Orientada a Objetos en ABAP.
- Puede ocurrir que Clases similares deban proporcionar funcionalidades parecidas, pero las Implementaciones son diferentes. Por ejemplo en las Clases Cuenta Corriente y Cuenta de Ahorro el cálculo de las comisiones del año es igual, solo que deben actuar sobre distintos Objetos, y el usuario no debe preocuparse del tipo de cada cuenta.
2- Qué son las Interfaces?
Son estructuras independientes que se pueden implementar en una Clase para extender el ámbito de esa Clase.
El ámbito específico de una Clase está definido por sus Componentes y sus Secciones de Visibilidad.
- Los Componentes Públicos definen su ámbito público (Atributos y Parámetros de Métodos para todos los Usuarios).
- Los Componentes Protegidos definen su ámbito respecto a sus Subclases. Las Interfaces lo extienden añadiendo sus Componentes a la Sección Pública, y permite que los Usuarios accedan a diferentes Clases por un punto en común.
- Las Interfaces junto con la Herencia son los pilares básicos del Polimorfismo, ya que permiten que un sólo Método con una Interface se comporte distinto en diferentes Clases.
- Si una Clase no tiene ningún Componente Público específico, la Interface describe el ámbito público de la Clase.
3- Definición de una Interface
Se pueden definir Globalmente en el Repositorio R/3 o Localmente en el programa ABAP utilizando Código ABAP entre las sentencias INTERFACE<nombre de la interface> y ENDINTERFACE.
Contiene la Declaración de sus Componentes (Atributos, Métodos y Eventos) y no tienen que ser asignados a ninguna Sección de Visibilidad (automáticamente pertenecen a la Sección Pública de la Clase) ni tienen una parte de Implementación (sus Métodos son implementados en la Clase).
4- Implementación de Interfaces
Cuando se implementa una Interface en una Clase, sus Componentes se añaden a la Sección Pública de la Clase y se lo puede direccionar utilizando como nombre lo siguiente <nombre de la Interface~nombre del Componente>
La Clase debe implementar los Métodos de las Interfaces implementadas en ella utilizando la sentencia METHOD<nombre de la Interface~nombre del Método>
Las Interfaces pueden ser implementadas en diferentes Clases, las cuales se ven ampliadas con los mismos Componentes, aunque los Métodos pueden ser implementados en forma distinta en cada Clase.
5- Referencias a Interfaces
Las Variables Referenciadas permiten acceder a los Objetos. Se pueden crear Variables Referenciadas a una Interface y puede contener referencias a los Objetos de las Clases que implementen esa Interface.
Para definir una Referencia a una Interface se usa la adición TYPE REF TO <nombre de la Interface>. LaInterfase debe haberse declarado antes en el programa.
Una Variable Referenciada con el Tipo Referenciado a una Interface se llama Variable Referenciada a una Interface oReferencia a Interface. <ireferencia>-><nombre de Componente> Con esto se puede acceder a todos losComponentes Visibles de la Interface del Objeto al cual la Referencia está apuntando y le permite al Usuarioacceder a todos los Componentes que fueron añadidos a su definición al implementar la Interface.
6- Direccionar y Asignar Objetos Usando Referencias a Interfaces
Para crear un Objeto de la Clase, primero se debe haber declarado una Variable Referenciada con Referencia a la Clase.
Si la Clase implementa una Interface, usando <ireferencia> = <creferencia> para hacer que la Referencia a Interface apunte al mismo Objeto que la Referencia a Clase.
Si la Interface contiene un Atributo y un Método Dependientes de Instancia, se pueden direccionar los Componentes
Para acceder a un Atributo usaremos <creferencia>->nombre de la Interface~nombre del Atributo>
Para acceder a un Método CALL METHOD <creferencia>->nombre de la Interface~nombre del Método>
Usando la Variable Referenciada a una Interface
Para acceder a un Atributo usaremos <ireferencia>-><nombre del Atributo>
Para acceder al Método CALL METHOD <ireferencia>->nombre del Método>
Si están implicados los Componentes Estáticos de las Interfaces, sólo se puede usar el Nombre de la Interface para acceder a las Contantes, y para acceder usaremos <nombre de la Interface>=><nombre de la Constante>
Para todos los demás Componentes Estáticos de una Interface, sólo se pueden usar Referencias a Objetos o la Clase que implementa la Interface,
Para acceder a un Atributo usaremos <clase>=><nombre de la Interface~nombre del Atributo>
Para acceder al Método Estático CALL METHOD <class>=>intf~meth>
7- Ejemplo de Interfaces
En el siguiente ejemplo de programa que utiliza Interfaces, se declara una llamada ESTADO y las Clases CONTADOR y BICICLETA que tienen en la Sección Pública declarada la Interface ESTADO.
INTERFACE estado.
METHODS imprimir.
ENDINTERFACE.
CLASS contador DEFINITION.
PUBLIC SECTION.
INTERFACES estado.
METHODS incrementar.
PRIVATE SECTION.
DATA cuenta TYPE i.
ENDCLASS.
CLASS contador IMPLEMENTATION.
METHOD estado~imprimir.
WRITE: / 'La cuenta en el contador es: ', cuenta.
ENDMETHOD.
METHOD incrementar.
ADD 1 TO cuenta.
ENDMETHOD.
ENDCLASS.
CLASS bicicleta DEFINITION.
PUBLIC SECTION.
INTERFACES estado.
METHODS manejar.
PRIVATE SECTION.
DATA velocidad TYPE i.
ENDCLASS.
CLASS bicicleta IMPLEMENTATION.
METHOD estado~imprimir.
WRITE: / 'La velocidad de la bicicleta es: ', velocidad.
ENDMETHOD.
METHOD manejar.
ADD 10 TO velocidad.
ENDMETHOD.
ENDCLASS.
Dentro del Evento START-OF-SELECTION,
- Se crean los Objetos CUENTA y BICI.
- Se ejecutan los Métodos CUENTA->INCREMENTAR y BICI->MANEJAR
- Se almacenan los resultados en la Tabla TI_ESTADO
- Y se recorre la Tabla llamando al Método IMPRIMIR
DATA cuenta TYPE REF TO contador,
bici TYPE REF TO bicicleta,
estado TYPE REF TO estado,
ti_estado TYPE TABLE OF REF TO estado.
START-OF-SELECTION.
CREATE OBJECT: cuenta, bici.
DO 5 TIMES.
CALL METHOD: cuenta->incrementar,
bici->manejar.
ENDDO.
APPEND: cuenta TO ti_estado,
bici TO ti_estado.
LOOP AT ti_estado INTO estado.
CALL METHOD: estado->imprimir.
ENDLOOP.
- Interfaces Globales
- Se pueden definir a través del Repositorio R/3 utilizando la Trx SE24.
- Son almacenadas en un Tipo Especial de Programa ABAP llamado Interface Pool que es del Tipo J y sirve como contenedor del respectivo Tipo de Objeto.
- Cada Pool de Interfaces contiene la definición de una sola Interface.
- Este programa se genera automáticamente cuando se crea la Interface Global.
- Un Pool de Interfaces es comparable a un Modul Pool o a un Grupo de Funciones. No contienen ninguna sentencia ejecutable.
- Cuando se implementa una Interface en una Clase, la Definición de la Interface queda implícitamente incluida en la Definición de la Clase.